PROC K_RECTODUMP
;Version 2
GOTO BEGIN
;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name:  K_RECTODUMP    
;#		   	MMS-F Name:  RECORD_TO_DUMP_1
;#					   RECORD_TO_DUMP_1_S  	 
;#		   	SUM Issue:  3E   	
;#			Simulator Validation Status:	Complete
;#
;#		1.2	Date Created:  30-MAR-95	
;#			    Revision:	1. 24-MAY-95	HB 
;#						2.	24-OCT-95	TB 
;#
;#		1.3	Change Description:	
;#
;#			1. Added WAIT statement to configure local TPOCC switch for 
;#			   playback.  Added TNIF LOAD and HISTORY statements.
;3			2.	SUM 3E updated.
;#
;#		1.4	Point of Contact:  GMiller	
;#			FOT Author:  HBenefield  	ATSC/SOHO	286-4799
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#
;#			Change the TM mode from record to dump.
;#
;#		2.2	Intended Use:
;#
;#			Change the TM mode from record to dump.
;#
;#		2.3	Duration:	7 min 45 sec
;#
;#		2.4 References: D_TR_STATUS or D_SSR_STAT_N
;#
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			None
;#
;#		3.2	Critical Activities
;#
;#			None
;#
;#		3.3	Special Constraints or Activities
;#
;#			None
;#**************************************************************************
;#	4.0	STEPS:

BEGIN:

LOCAL TID,REC,X1,ADDR

IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
	/CLEAR		;Clearing the Command Buffer.
ENDIF

RETRY0:
ASK "What telemetry subformat is the DHSS in (1-4)?"TID
IF ( (TID < 1) OR (TID > 4) ) THEN
	WAIT	;Invalid TM Subformat. TRY again.
	GOTO RETRY0
ELSE
ENDIF

WAIT UNTIL(P@KKTMFID = "MR/HR $TID")
WAIT UNTIL(P@KKTMMODE = "RECORD")

WAIT;Configure local TPOCC switch for playback:  FE ch 3 (in) to FE ch 2 (out)
TNIF LOAD 2 SOHO2.DSD
HISTORY OPEN FRAME TREC

RETRY1:
ASK "WHICH RECORDER IS BEING USED (1-TR/2-SSR)?"REC
IF ( (REC < 1) OR (REC > 2) ) THEN
	WAIT	;Invalid RECORDER. TRY again.
	GOTO RETRY1
ELSE
ENDIF

IF (REC=1) THEN
	IF (P@DSTR1SBY.NE."STAND-BY") THEN
		/DZTR1SBN		;Tape-rec 1 to standby (NOM)
		WAIT		;Verify contents of command buffer
		/SEND
	ELSE
	ENDIF

	WAIT UNTIL (P@DSTR1SBY = "STAND-BY")
	WAIT	;Record TR position on pass plan.
ELSE
	IF ((P@DKSSNMOD="RECORD") AND (P@DSSSNCKA="ACTIVE")) THEN
		/DZSSNSBN		;Set the SSR in standby mode
		WAIT		;Verify contents of command buffer
		/SEND
	ELSE
	ENDIF

	WAIT UNTIL (P@DKSSNMOD = "STAND-BY")

	WAIT	;Record the logical adress of the current memory page on pass plan

	ASK "WILL DUMP START FROM CURRENT POSITION OF DUMP/RECORD POINTER (Y/N)"
	LET ANSWER = %UPPER(ANSWER)
	IF (ANSWER="Y") THEN
		GOTO STUB
	ELSE
		ASK "ENTER LOGICAL ADDRESS OF DESIRED MEMORY PAGE"ADDR

		LET X1 = %HEX( H'$ADDR' * H'2' + H'2000',4) 

		/DZSSNGEN,$X1	;Send memory page selection cmd
		WAIT			;Verify command buffer contents
		/SEND
		WAIT UNTIL (DKSSADMP = H'$ADDR')	;Check value of logical address of 
			;current memory page, at updated record/dump pointer position
	ENDIF
	STUB:

	/DZSSND1N		;SSR N to dump (A1 1F) mode cmd (N)
	WAIT			;Verify contents of command buffer
	/SEND

	WAIT UNTIL(P@DKSSNMOD = "DUMP")
	WAIT UNTIL(P@DKSSNCHL = "CHAN. 1")
	WAIT UNTIL(P@DSSSNCKA = "NOT.ACT.")
ENDIF	

/KNK1ET5$TID		;TM rate/mode = HR/dump science $TID
WAIT		;Verify contents of command buffer
/SEND

WAIT UNTIL(P@KKTMFID = "MR/HR $TID")
WAIT UNTIL(P@KKTMMODE = "PLAYBACK")

IF (REC=1) THEN
	/DZTR1PAN		;Tape-rec 1 to repro/A (NOM)
	WAIT		;Verify contents of command buffer
	/SEND

	WAIT UNTIL (P@DSTR1REP = "REPRO.")
ELSE
	WAIT UNTIL (P@DSSSNCKA = "ACTIVE")
	WAIT	;Check for change of logical memory page appx every 3 seconds
ENDIF

;#************************************************************************** 
;#	5.0	Final Constraints
;#
;#		When in dump mode, the SSR only accepts the standby ML command.
;#		When in dump mode, if the beginning of the memory stack is reached,
;#			the SSR returns in the standby mode.
;#
;#**************************************************************************
ENDPROC