PROC N_FL_NM_SW_ON

;Version 9

GOTO BEGIN

;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1 FOT Name:	N_FL_NM_SW_ON	
;#		    MMS-F Name: SWN_ON (SWAN experiment ops Man, Issue 1.5, sect.6)	
;#		    SUM Issue:	N/A
;#		    Simulator Validation Status: TBS
;#
;#		1.2	Date Created:	NOV 02, 1994	
;#			    Revision:	1. 1-5-95
;#						2. 21-JAN-95	MH
;#						3. 21-JAN-95	CQ
;#						4. 24-JAN-95	MH
;#						5. 24-JAN-95   HB
;#						6. 25-APR-95   CQ
;#						7. 04-MAY-95   CQ
;#						8. 06-OCT-95	CQ
;#						9. 24-OCT-95   CQ
;#
;#		1.3	Change Description:	
;#
;#			1. Suggestions from W.Schmidt 15.12.94
;#			2. Edited current checks for NIP and NIEU to check for mA
;#			3. Added wait until statement for line 114 to 128
;#			4. Added proc call to K_EXP_MN_ENA
;#			5. Added WAIT statement after KNK12000.  Added closing paran-
;#			   thesis in NKRESET statement.  Deleted last two WRITE and last
;#			   WAIT statements.
;#			6. Change K_EXP_MON_ENA prc position from line 94 to line 82, and
;#			   changed the wait until statement to sv.
;#			7. Added commands (KNNPWAFN,KNNPWBFN,KNNPWAFR,KNNPWBFR).
;#			8. Moved K_EXP_MON_ENA proc from line 87 after cmd buffer clear
;#			   statement to line 133 before monitoring scenario.  This was
;#			   requested by PI.
;#			9. Changed proc's name from TS to FL, there is no TSTOL changes
;#			   no further input from PI since GSCT#3.
;#
;#   
;#		1.4	Point of Contact:	
;#			FOT Author:	CQ		ATSC/SOHO	805-3750
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#
;#			This procedure will do the following:
;#			- selection of S/C data path nominal (pulse cmd 1)
;#			- selection of power line nominal (pulse cmd 3)
;#			- selection of CPU nominal (pulse cmd 5)
;#			- S/C-power on to the nominal power line A
;#			- Monitoring of housekeeping data
;#
;#		2.2	Intended Use:
;#
;#			SWAN Switch on/off procedures
;#
;#		2.3	Duration:	< 3 mins
;#
;#		2.4  References: SWAN Experiment Operations Manual, Issue 1.5, Sec.6
;#					  MMS-UK Database printout files SWN_ON and SWN_OFF,
;#					  last edited 06.05.1994
;#
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			None
;#
;#		3.2	Critical Activities
;#
;#			N/A
;#
;#		3.3	Special Constraints or Activities
;#
;#			N/A
;#
;#**************************************************************************
;#	4.0	STEPS:

BEGIN:

; Telecomand Sequence:

IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
/CLEAR					; Clearing the Command Buffer
ENDIF


;SWITCH OFF ALL POWER LINES TO SWAN INSTRUMENT BEFORE MOVING THE
;INSTRUMENT'S POWER RELAY

/KNNPWAFN
/KNNPWBFN
/KNNPWAFR
/KNNPWBFR
WAIT					; Verify command buffer contents
/SEND

WAIT 5				; Wait for 5 seconds

/NCDATNN					; SWAN pulse command 1: select nominal data path
/NCPWRNN					; SWAN pulse command 3: select nominal power input
/NCCPUNN					; SWAN pulse command 5: select nominal CPU board
/KNNPWANN					; Nominal power for SWAN instrument on
WAIT 					; Verify command buffer contents
/SEND

WAIT UNTIL (P@NSPWA = "ON")	; Verify S/C-digital flag NSPWA = ON MAX. WAIT 
	  					; TIME IS 60 SEC, THEN ERROR EXIT IF FLAG IS NOT 
						; ON READ FROM NEXT TM-PACKAGE


SV P@NSPWA				; Activate monitoring SWAN A status
SV P@NSPWB				; Activate monitoring SWAN B status

;NIPWA	S/C-Primary current monitor

WAIT UNTIL ((P@NIPWA > 0.07) and (P@NIPWA < 0.35))

SV P@NIPWA				; Activate monitoring SWAN A current
SV P@NIPWB				; Activate monitoring SWAN B current

;NOTE: Previous package may indicate NIPWA > 0.5A, as loading from PROM has 
;high power consumption

/KNK12000,0008				; Send LOBT command to SWAN instrument
WAIT				;Verify contents of command buffer
/SEND

;NOTE: The delay between KNNPWANN and the LOBT-Command should not be larger
;      than 8*MFP ( < 120 sec ), as the SWAN instrument times out after 10*
;	  MFP following the switch-on, initializing the LOBT to 0

S K_EXP_MON_ENA	;Enable experiment monitoring

; Monitoring:
; S/C-parameters: wait 4*MFP (about 60s) after the LOBT-command.  Monitoring
; the following TM parameters:

WAIT UNTIL ((P@NIP>200) and (P@NIP<400))	TIMEOUT 180 ; Instrument primary current

SV P@NSDATPTH  		; Data path selection, expected : NOM
 
SV P@NSCPUSEL 		 	; CPU selection, expected : NOM

SV P@NSSU1 			; SU1 status, expected : ON

SV P@NSSU2 			; SU2 status, expected : ON

SV P@NKMODER 			; Checksum error detection (mode) SWAN, expected : OK

SV P@NKSEQER 			; Checksum error detection (obs.) SWAN, expected : OK

SV P@NKSYSER 			; Checksum error detection (syst.)SWAN, expected : OK

SV P@NKRESET 			; CPU reset detection, expected : NO RESET

WAIT UNTIL ((P@NIEU>100) and (P@NIEU<300)) TIMEOUT 60 ; Secondary total current


;#************************************************************************** 
;#	5.0	Final Constraints
;#
;#		NONE
;#
;#**************************************************************************

ENDPROC