PROC N_FL_SU_RESET
;Version 0	
GOTO BEGIN
;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name: N_FL_SU_RESET 
;#		   	MMS-F Name: N/A 	 
;#		   	SUM Issue:  N/A
;#			Simulator Validation Status:
;#
;#		1.2	Date Created: 23-NOV-96
;#			    Revision:  
;#
;#		1.3	Change Description:	
;#
;#			None.
;#
;#		1.4	Point of Contact: Ben Berner	
;#			FOT Author: Ben Berner 	ATSC/SOHO	286-4799
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#
;#			Cycles power to the low-voltage power supplies of both sensor
;#			units. Stops any ongoing observation.
;#			
;#
;#		2.2	Intended Use:
;#
;#			Recovery from sensor unit low-voltage power supply trip.
;#		
;#		2.3	Duration:	
;#
;#		2.4	References:
;#
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			None
;#
;#		3.2	Critical Activities
;#
;#			None
;#
;#		3.3	Special Constraints or Activities
;#
;#			All RAW telemetry values for one of the sensor units should
;#			be zero. If not, this procedure will not correct the 
;#			anomalous condition.
;#     		
;#**************************************************************************
;#	4.0	STEPS:

BEGIN:


IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
	/CLEAR; Clearing the Command Buffer.
ENDIF

LOCAL TCVALID

;--------------------------------------------
; If any of the following telemetry checks
; fail, there may be a more serious anomaly
; involved. All raw values for one of the 
; sensor units should be zero. Type 'GO TO
; OUT' if one of the checks does not verify
; immediately, and contact a member of the
; SWAN experiment team.
;--------------------------------------------
WAIT; Go after reading above message.

WAIT UNTIL((NXSU1IMP = 0).OR.(NXSU2IMP = 0))
WAIT UNTIL((NXSU1OMP = 0).OR.(NXSU2OMP = 0))
WAIT UNTIL((NISU1HC = 0).OR.(NISU2HC = 0))
WAIT UNTIL((NTSU1OM = 0).OR.(NTSU2OM = 0))

IF (((NXSU1IMP = 0).AND.(NKEUMON = 0)).OR.;;
((NXSU2IMP = 0).AND.(NKEUMON = 1))) THEN
	WAIT UNTIL (N+EU = 0)
	WAIT UNTIL (NIEU = 0)
	WAIT UNTIL (NIP = 0)
	WAIT UNTIL (NTEUPS = 0)
	WAIT UNTIL (NTMCU = 0)
ENDIF

LET TCVALID = NSTCVAL
;--------------------------------------------
; Stop any ongoing observation.
;--------------------------------------------
/CMD NBSEQ1,0000,0000,0182,9005
/SEND
WAIT UNTIL (NSTCVAL = TCVALID+1)

LET TCVALID = NSTCVAL
;--------------------------------------------
; Cycle power to the low-voltage power
; supply for sensor unit #1.
;--------------------------------------------
/CMD NBSU1OF
/SEND
WAIT UNTIL (NSTCVAL = TCVALID+1)

/CMD NBSU1ON
/SEND
WAIT UNTIL (NSTCVAL = TCVALID+2)

LET TCVALID = NSTCVAL
;--------------------------------------------
; Cycle power to the low-voltage power
; supply for sensor unit #2.
;--------------------------------------------
/CMD NBSU2OF
/SEND
WAIT UNTIL (NSTCVAL = TCVALID+1)

/CMD NBSU2ON
/SEND
WAIT UNTIL (NSTCVAL = TCVALID+2)

;--------------------------------------------
; All SWAN mnemonics should return within
; limits. This may take several formats.
; Notify a SWAN experiment team member about
; this recovery.
;--------------------------------------------
WAIT; Go after reading above message.

OUT:
;#************************************************************************** 
;#	5.0	Final Constraints
;#
;# ALL MNEMONICS SHOULD RETURN WITHIN LIMITS
;# AFTER SEVERAL FORMATS. IF NOT, CONTACT A
;# SWAN EXPERIMENT TEAM MEMBER.
;#
;#**************************************************************************
RETURN
ENDPROC