PROC U_FL_MAIN_RD
;VERSION 4

IF (P@NRT_STATE#TELECOMMAND = "ENABLED") THEN
/NRT TPUT PAUS
ELSE
ENDIF

GOTO BEGIN
;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name:	U_FL_MAIN_RD
;#		    MMS-F Name:	U_TS_MAIN(config)
;#		    SUM Issue:  ISSUE 1 UVCS G/S Test Procedures
;#			Simulator Validation Status:  none
;#
;#		1.2	Date Created:	29-SEP-94
;#				Revision:  1. 02-AUG-95  BS		
;#						 2. 25-AUG-95  BS
;#						 3. 14-SEP-95  BS
;#						 4. 25-OCT-95  BS
;#
;#		1.3	Change Description:	
;#
;#			1. Delete checksumming of EEPROM. Update cfgmon name. Add wait
;#			   wait for USPWHT. Delete following cmds w/TM checks:
;#			   /UBMDIS, /UBPXG, /UBFGSUDS, /UBFGSFDS, /UBMDST.
;#			2. Change waits for UKJUSEG = SEGMENT -> UKJUSEG = H'EC41'.
;#			   UKJUOFF = OFFSET -> UKJUOFF = H'0004'. Make into RPR.
;#			3. Change lower limit for UIPWA. Delete cfgmon call. Add wait
;#			   for USMD = INIT. Change data words for /UBJU to EC7D,000C
;#			   Delete checks for UHDP0-3. New hex values for waits for
;#			   UKJUSEG(EC7D) and UKJUOFF(0004).  Delete hard wait after
;#			   /UBJU.
;#			4. Change check for LR to LOW RATE. Remove P@s from checks 
;#			   for ukjuseg,ukjuoff. New values to check for in checks of
;#			   ukjuseg,ukjuoff.
;#
;#		1.4	Point of Contact: CCazeau		ATSC/SOHO	286-6374	
;#			FOT Author:	BRETT SAPPER	ATSC/SOHO	286-4799
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#
;#			ACTIVATE MAIN UVCS SOFTWARE
;#
;#		2.2	Intended Use:
;#
;#			ACTIVATE MAIN UVCS SOFTWARE
;#
;#		2.3	Duration:	20 Min.
;#
;#		2.4 References:
;#
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			None
;#
;#		3.2	Critical Activities
;#
;#			None.
;#
;#		3.3	Special Constraints or Activities
;#
;#			NONE.
;#**************************************************************************
;#	4.0	STEPS:
;#		
;
BEGIN:

IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
	/CLEAR		;Clearing the Command Buffer.
ENDIF

LOCAL NUM,I,ID,CHECK

WAIT UNTIL (P@USPWA = "OFF")		;UVCS power A status 
WAIT UNTIL (P@USPWB = "ON")		;UVCS power B status
WAIT UNTIL ((P@UIPWB > 0.35) AND (P@UIPWB < 2.0))	;UVCS current B

WAIT UNTIL (P@USMD = "INIT")
WAIT UNTIL (P@USPWHT = 	"ON")  			;Heater power status
WAIT UNTIL (P@USPWDO =	"OFF")  		;OVI detector power status
WAIT UNTIL (P@USPWDL =	"OFF")  		;LYA detector power status
WAIT UNTIL (P@USPWDV = 	"OFF")  		;Visible light detector power status

/UBJU,EC7D,000C			;Jump to new execution address
						;segment = EC7D, offset = 000C
WAIT 					;VERIFY BUFFER CONTENTS
/SEND

WAIT UNTIL (P@USDPID = "INIT")  		;Data content packed ID
WAIT UNTIL (P@USMD = "STBY") 			;Software Mode

IF (P@KKTMFID <> "LOW RATE")THEN
	WAIT UNTIL (UKJUSEG = H'EC7D')
	WAIT UNTIL (UKJUOFF = H'000C')
ELSE
	WRITE "UNABLE TO VERIFY IN TM DUE TO LR DATA"
	WAIT 10
ENDIF

/KNK12000,0004				;Update LOBT for UVCS only
WAIT				;VERIFY BUFFER CONTENTS
/SEND

WAIT	;VERIFY LOBT UPDATED FOR UVCS (VERIFY W/ EXPERIMENTER)

;#************************************************************************** 
;#	5.0	Final Constraints
;#
;#		NONE.
;#
;#**************************************************************************

IF (P@NRT_STATE#TELECOMMAND = "PAUSE-ENAB") THEN
/NRT TPUT RSUM
/CMSMSG,UVCS,'Procedure U_FL_MAIN_RD has completed'
ELSE
ENDIF

ENDPROC