PROC U_FL_PWRON_PR
;VERSION 4

GOTO BEGIN
;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name:  U_FL_PWRON_PR	
;#		    MMS-F Name:	U_TS_PWRON
;#		    SUM Issue:	ISSUE 1 UVCS G/S Test Procedures
;#			Simulator Validation Status:  None
;#
;#		1.2	Date Created:	27-SEP-94
;#				Revision:	1. 01-AUG-95  BS
;#						2. 25-AUG-95  BS
;#						3. 14-JUL-95  BS
;#						4. 25-OCT-95  BS
;#
;#		1.3	Change Description:	
;#
;#			1. Delete RPR/NRT references. Delete switch on.off of substitution
;#			   heaters. Put in correct cmd for LCL turn on KNUPWANN. Delete
;#			   check for USPWM. TM check UKCVCPT -> UKCVACPT. 
;#			2. Correct syntax for cfgmon off cmd.
;#			3. New lower limit for UIPWA. Delete cfgmon call. Add wait
;#			   for USDPID. Delete cmd UBPWSELA and verification. Make if
;#			   for TM checks not valid in low rate.
;#			4. Correct check for ustctog now check = 0. TM rate checks for
;#			   LOW RATE vice LR.
;#
;#		1.4	Point of Contact:  CCazeau		ATSC/SOHO	805-3649	
;#			FOT Author:	BRETT SAPPER	ATSC/SOHO	805-3749
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#
;#			UVCS Power On
;#
;#		2.2	Intended Use:
;#
;#			This procedure switches on UVCS main power (primary side)  
;#			and puts the instrument in the INIT mode.
;#
;#		2.3	Duration:	TBD
;#
;#		2.4 References: 
;#
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			None
;#
;#		3.2	Critical Activities
;#
;#			NONE.
;#
;#		3.3	Special Constraints or Activities
;#
;#			NONE.
;#
;#**************************************************************************
;#	4.0	STEPS:
;#		
;
BEGIN:
LOCAL I
IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
	/CLEAR		;Clearing the Command Buffer.
ENDIF

LOCAL LAST_TOG

WAIT UNTIL (P@USPWA = "OFF") 		;UVCS power A status at S/C.
WAIT UNTIL (P@USPWB = "OFF") 		;UVCS power B status at S/C.

/KNUPWANN		;Switch on UVCS power A, Primary
 WAIT			;VERIFY CONTENTS OF BUFFER
/SEND

WAIT UNTIL (P@USPWA = "ON")		;UVCS power A status 
WAIT UNTIL (P@USPWB = "OFF")		;UVCS POWER B STATUS
WAIT UNTIL (P@UIPWA > 0.35) AND (P@UIPWA < 2.0)	;UVCS CURRENT A

START K_EXP_MON_ENA				;Start proc to enable experiment monitoring.

WAIT UNTIL (P@USDPID = "INIT")
WAIT UNTIL (P@USPWHT = "ON")    ;Heater power status
WAIT UNTIL (P@USPWDO = "OFF")   ;OVI detector power status
WAIT UNTIL (P@USPWDL = "OFF")   ;LYA detector power status
WAIT UNTIL (P@USPWDV = "OFF")   ;Visible light detector power status
WAIT UNTIL (P@USMD = "INIT")    ;Software mode
WAIT UNTIL (USTCTOG = 0 )     ;S/C toggle bit state
WAIT UNTIL (P@USRSTYP = "POR")  ;Last reset type (power on reset)

IF (P@KKTMFID <> "LOW RATE")THEN
	WAIT UNTIL (UKTCRJCT = H'0000') ;S/C reject counter
	WAIT UNTIL (UKMLACPT = H'0000') ;Memory load accept counter
	WAIT UNTIL (UKMLRJCT = H'0000') ;Memory load reject counter
	WAIT UNTIL (UKCVACPT = H'0000')  ;Command validity accept counter
	WAIT UNTIL (UKCVRJCT = H'0000') ;Command validity reject counte
	WAIT UNTIL (UKIMEXEC = H'0000') ;Executed immediate command counter.
	WAIT UNTIL (UKIMNTEX = H'0000') ;Non-executed immediate command counter


	LET LAST_TOG = USTCTOG
	FOR I = 1 TO 3 DO
		WAIT 	;ANALYST RECORD THESE VALUES.
		SV UKMLACPT
		SV UKCVACPT
		SV UKIMEXEC

 		/UBNO
		/SEND

		WAIT UNTIL (USTCTOG <> LAST_TOG)
		WAIT	;ANALYST VERIFY UKMLACPT, UKCVACPT
			;AND UKIMEXEC INCREMENTED BY 1.
		SV UKMLACPT
		SV UKCVACPT
		SV UKIMEXEC

		LET LAST_TOG = USTCTOG

	ENDDO
ENDIF

;#************************************************************************** 
;#	5.0	Final Constraints
;#
;#		NONE.
;#
;#**************************************************************************
ENDPROC