PROC V_FL_LOCK_LOI 
;Version 2
GOTO BEGIN
;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name:	 V_FL_LOCK_LOI   
;#		   	VIRGO Name:  Lock Guiding of LOI Sensor (PROC 22)  	 
;#		   	Issue/Rev:  2.8  	
;#			Simulator Validation Status:
;#
;#		1.2	Date Created:  08-AUG-95  
;#			    Revision:  1. 30-AUG-95	HB
;#						2. 01-FEB-96   CQ
;#		1.3	Change Description:	
;#
;#			1. Made flight ready.  Changed name from v_ts_lock_loi.  No 
;#			   TSTOL changes.
;#			2. Modify the proc per OCD #184 submitted by PI.
;#
;#		1.4	Point of Contact:  CCazeau	
;#			FOT Author:  HBenefield  	ATSC/SOHO	286-4799
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#
;#			Procedure to freeze the guiding system to the optical zero 
;#			position to do LOI for flat fielding test.
;#
;#		2.2	Intended Use:
;#
;#			Freeze the guiding system to the optical zero position for LOI
;#			flat fielding test.
;#		
;#		2.3	Duration:	9 minutes.
;#
;#		2.4	References:
;#			PAGES:  V_STATUS, V_TEMP_STAT, V_VOLT_HKCAL, I_EXP_STAT
;#
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			Z and Y axis positions.
;#
;#		3.2	Critical Activities
;#
;#			None.
;#
;#		3.3	Special Constraints or Activities
;#
;#			The VIRGO commands execute on a 3 minute cycle.  Only one
;#			command can be sent between command executions.
;#     		
;#**************************************************************************
;#	4.0	STEPS:

BEGIN:

LOCAL ZPOS,YPOS

IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
	/CLEAR		;Clearing the Command Buffer.
ENDIF

ASK "Enter the desired Z-axis position (2 digits hex)"ZPOS
ASK "Enter the desired Y-axis position (2 digits hex)"YPOS

/VZML,60$ZPOS	;Z-axis fixed ON $ZPOS-position
WAIT			;Verify contents of command buffer.
/SEND
WAIT UNTIL (VSTCRETN=H'60$ZPOS')	;Verify TC return

/VZML,60$YPOS	;Y-axis fixed ON $YPOS-position
WAIT			;Verify contents of command buffer.
/SEND
WAIT UNTIL (VSTCRETN=H'60$YPOS')	;Verify TC return

/VZML,90BF	;REF1, SPM-A, PMO-A, BU:CYCLIC PMB-B, PMO-B
WAIT			;VERIFY CONTENS OF COMMAND BUFFER
/SEND

WAIT UNTIL (VSTCRETN = H'90BF')	;VERIFY TC RETURN

/VZML,800B	;COVER SPM-B OPEN
WAIT			;VERIFY CONTENTS OF COMMAND BUFFER
/SEND

WAIT UNTIL (VSTCRETN = H'800B')	;VERIFY TC RETURN

WAIT 720		;WAIT 12 MINS BEFORE PROCEEDING

/VZML,8003	;COVER SPM-B CLOSED
WAIT			;VERIFY CONTENTS OF COMMAND BUFFER
/SEND

WAIT UNTIL (VSTCRETN = H'8003')	;VERIFY TC RETURN

;#************************************************************************** 
;#	5.0	Final Constraints
;#
;#		None.
;#
;#**************************************************************************
ENDPROC