PROC V_FL_PMOA_TST
;Version 6
GOTO BEGIN
;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name:  V_FL_PMOA_TST
;#		   	VIRGO Name:  Radiometer PMO6-V-A Test/Commissioning (PROC 9)	 
;#		   	Issue/Rev.:   2.5
;#			Simulator Validation Status:
;#
;#		1.2	Date Created:  17 JAN 95
;#			    Revision: 	1.  31-MAR-95   CG
;#						2.  21-APR-95	HB
;#						3.  25-APR-95	CG
;#						4. 08-AUG-95	HB
;#						5. 30-AUG-95	HB
;#						6. 23-MAR-95	HB
;#
;#		1.3	Change Description:	
;#
;#			1.  Updated header information in 1.1, 1.2, 1.3, 2.1, & 2.2.
;#			    Changed commands to VZML with new words. Added 2 WAIT
;#			    UNTILs.  Deleted 19 lines at end of proc including 2
;#			    /VZPMOADC commands, /VZPMOAD0 & 7 WAIT UNTILs.
;#			2. Added WAIT 240 statements prior to the second and third
;#			   commands.
;#			3. Deleted WAIT 240 statements prior to the second and third
;#			   commands.
;#			4. Added version number.  Added page references.  Removed TBDs.
;#			   Added comments.  
;#			5. Made flight ready.  Changed name from v_ts_pmoa_tst.  Changed
;#			   data word in second VZML from 90B8 to 90B6.  Changed
;#			   associated TM checks.  Changed TM checks to eliminate hard
;#			   WAITS.
;#			6. Replaced VZML,300C with VZML,3008.
;#
;#		1.4	Point of Contact:  Carline Cazeau
;#			FOT Author:  HBenefield	ATSC/SOHO	286-4799
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#
;#			This procedure deals with radiometer PMO6-V-A, puts the shutter
;#			mechanism to automode to be ready for a cover test.
;#
;#		2.2	Intended Use:
;#
;#			This procedure is part of a sequence of procedures to run all the			
;#			different subunits & instruments.
;#
;#		2.3	Duration:	20 minutes
;#
;#		2.4 	References:
;#			PAGES:  V_STATUS, V_TEMP_STAT, V_VOLT_HKCAL, I_EXP_STAT
;#
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			None.
;#
;#		3.2	Critical Activities
;#
;#			None.
;#
;#		3.3	Special Constraints or Activities
;#
;#			The VIRGO commands execute on a 3 minute cycle.  Only one
;#			command can be sent between command executions.
;#
;#**************************************************************************
;#	4.0	STEPS:

BEGIN:

LOCAL EKS, WHY, ZEE

IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
	/CLEAR		;Clearing the Command Buffer.
ENDIF

/VZML,703C		;Switch ON PMO-A.
WAIT				;Verify contents of command buffer.
/SEND
WAIT UNTIL (VSTCRETN = H'703C')	;Verify TC return

LET EKS = VSPDU MOD 64
WAIT UNTIL (EKS = B'111100')	;Check PDU status

WAIT	;Check current consumption VIPWA (.02 A increase expected)

/VZML,90B6		;Ref 1, SPM-A, PMO-A, BU:  PMOB I
WAIT				;Verify contents of command buffer.
/SEND
WAIT UNTIL (VSTCRETN=H'90B6')	;Check TC return

LET EKS = VSDAS MOD 32
LET WHY = (VSDAS - EKS)/32
LET ZEE = WHY MOD 2

WAIT UNTIL (ZEE = 1)	;Check DAS status (VSDAS = B'XX1X XXXX')

LET EKS = VS1PMA MOD 8
LET WHY = (VS1PMA - EKS)/8

WAIT UNTIL (WHY = 1)	;Check PMO6-A status (VS1PMA=B'1XXX')

LET EKS = VS1PMB MOD 8
LET WHY = (VS1PMB - EKS)/8

WAIT UNTIL (WHY = 0)	;Check PMO6-B status (VS1PMB=B'0XXX')

WAIT UNTIL (VSBUP=H'6')			;Check Backup status

/VZML,3008		;PMO-A:  LUD ena, shutter auto
WAIT				;Verify contents of command buffer.
/SEND
WAIT UNTIL (VSTCRETN=H'3008')	;Check TC return


;#************************************************************************** 
;#	5.0	Final Constraints
;#
;#		None.
;#
;#**************************************************************************
ENDPROC