PROC V_FL_PWROFF
;Version 5
GOTO BEGIN
;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name:  V_FL_NMPWROFF  
;#		   	VIRGO Name:  Nominal Power Off (PROC 4) 	 
;#		   	Issue/Rev.:  2.5   	
;#			Simulator Validation Status:
;#
;#		1.2	Date Created:  18 JAN 95
;#			    Revision:  1.  31-MAR-95  CG
;#						2. 21-APR-95	HB
;#						3. 31-MAY-95	CG
;#						4. 08-AUG-95	HB
;#						5. 31-AUG-95	HB
;#
;#		1.3	Change Description:	
;#
;#		   	1. Changed 1.1 Header information.  Changed 2
;#			   WAIT TIMEOUTs to 180.  Added WAIT to check VIPWA.
;#			   Deleted execution of Q_V_SUB_ON.
;#		   	2. Changed final WAIT statement to WAIT UNTIL (VIPWA=0). 
;#		   	3. Changed command mnemonics to new versions.
;#			4. Added version number.  Added page references.  Removed TBDs. 
;#			   Added WAIT after redundant command failure.  Added comments.
;#			5. Made flight ready.  Changed name from v_ts_nmpwroff.  
;#			   Combined with procedure v_ts_rdpwroff.    
;#
;#		1.4	Point of Contact:  Carline Cazeau
;#			FOT Author:  HBenefield	ATSC/SOHO	286-4799
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#
;#			This procedure turns off the experiment properly.
;#
;#		2.2	Intended Use:
;#
;#			Turn VIRGO OFF.
;#
;#		2.3	Duration:	5 minutes
;#
;#		2.4  References:
;#			PAGES:  V_STATUS, V_TEMP_STAT, V_VOLT_HKCAL, I_EXP_STAT
;#
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			Procedure call for K_EXP_MON_DIS
;#
;#		3.2	Critical Activities
;#
;#			None.
;#
;#		3.3	Special Constraints or Activities
;#
;#			The VIRGO commands execute on a 3 minute cycle.  Only one
;#			command can be sent between command executions.
;#
;#**************************************************************************
;#	4.0	STEPS:

BEGIN:

LOCAL ANS

IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
	/CLEAR		;Clearing the Command Buffer.
ENDIF

S K_EXP_MON_DIS	;Start procedure to disable experiment monitoring for VIRGO

IF (P@VSPWA = "ON") THEN
	/KNVPWAFN		;Switch OFF experiment, Branch 1 (Main)
	WAIT			;Verify command buffer contents
	/SEND

	WAIT UNTIL (P@VSPWA = "OFF") TIMEOUT 180	;Verify experiment, branch 1 OFF

	IF (P@VSPWA = "ON") THEN
		WRITE "THE NOMINAL COMMAND DID NOT WORK!"

		ASK "DO YOU WANT TO TRY THE REDUNDANT COMMAND?"ANS
		LET ANS=%UPPER(ANS)
		IF (ANS="Y") THEN
			/KNVPWAFR		;Switch OFF experiment, Branch 1 (Redundant)
			WAIT			;Verify command buffer contents
			/SEND

			WAIT UNTIL (P@VSPWA = "OFF") TIMEOUT 180  ;Verify experiment, branch 1
											;OFF

			IF (P@VSPWA = "ON") THEN
				WRITE "THE REDUNDANT COMMAND DID NOT WORK EITHER!"
				WAIT
			ELSE
			ENDIF
		ELSE
		ENDIF
	ELSE
	ENDIF
ELSEIF (P@VSPWB = "ON") THEN
	/KNVPWBFN		;Switch OFF experiment, Branch 2 (Main)
	WAIT			;Verify command buffer contents
	/SEND

	WAIT UNTIL (P@VSPWB = "OFF") TIMEOUT 180	;Verify experiment, branch 2 OFF.

	IF (P@VSPWB = "ON") THEN
		WRITE "THE NOMINAL COMMAND DID NOT WORK!"

		ASK "DO YOU WANT TO TRY THE REDUNDANT COMMAND?"ANS
		LET ANS=%UPPER(ANS)
		IF (ANS="Y") THEN
			/KNVPWBFR		;Switch OFF experiment, Branch 2 (Redundant)
			WAIT			;Verify command buffer contents
			/SEND

			WAIT UNTIL (P@VSPWB = "OFF") TIMEOUT 180	;Verify experiment, branch 2
										;OFF.

			IF (P@VSPWB = "ON") THEN
				WRITE "THE REDUNDANT COMMAND DID NOT WORK EITHER!"
				WAIT
			ELSE
			ENDIF
		ELSE
		ENDIF
	ELSE
	ENDIF
ELSE
	WRITE "THE INSTRUMENT IS ALREADY OFF"
	WAIT
ENDIF
	
IF (P@VSPWA = "OFF") THEN
	WAIT UNTIL (P@VIPWA=0)	;Check current consumption
ENDIF

IF (P@VSPWB = "OFF") THEN
	WAIT UNTIL (P@VIPWB=0)	;Check current consumption
ENDIF

;#************************************************************************** 
;#	5.0	Final Constraints
;#
;#		None.
;#
;#**************************************************************************
ENDPROC