PROC V_FL_PWRONA
;Version 6
GOTO BEGIN
;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name:  V_FL_PWRONA  
;#		   	VIRGO Name:  Flight Power ON to Save Mode (PROC 1)  	 
;#		   	Issue/Rev.:  2.5   	
;#			Simulator Validation Status:
;#
;#		1.2	Date Created:  12 Jan 95
;#			    Revision:  1. 31-MAR-95	CG
;#						2. 21-APR-95	HB
;#						3. 31-MAY-95	CG
;#						4. 08-AUG-95	HB
;#						5. 30-AUG-95	HB
;#						6. 26-OCT-95	HB
;#						7. 10-DEC-95	HB
;#
;#		1.3	Change Description:	
;#
;#			1.  Updated header titles & information.  Added 2 local
;#			    variables.  Changed 2 TIMEOUTS to 180. Changed memory load
;#			    command to VZML & added day flexibility.  Added 2 WAIT 180s.
;#			    Added WAIT for current consumption check.
;#			2. Changed WAIT 180 to WAIT 60 after VCGROND1.  Added WAIT 60
;#			   before the ASK statement.  Changed text of the ASK statement.
;#			   Changed final WAIT statement to describe the expected change
;#			   in the current.
;#			3.  Updated power on commands to new ones.
;#			4. Added version number.  Added page references.  Removed TBDs. 
;#			   Added WAIT after redundant command failure.  Added comments.
;#			   Added command VZML,7000 to reset PDU.
;#			5. Updated procedure to flight ready status per PI comments.
;#			   Changed name from V_TS_NOMPWRON.  Combined procedure with 
;#			   old procedure V_TS_REDPWRON.
;#			6. Added VCGROND2 for redundant branch.
;#			7. Changed procedure name from V_FL_PWRON to V_FL_PWRONA.
;#
;#		1.4	Point of Contact:  Carline Cazeau	
;#			FOT Author:  H. Benefield	ATSC/SOHO	286-4799
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#
;#			This procedure switches on VIRGO power and puts it in a save
;#			standby mode.  In this mode only subunits PS, DAS, and PDU are
;#			powered and all instruments are switched off.
;#
;#		2.2	Intended Use:
;#
;#			Power ON of VIRGO
;#
;#		2.3	Duration:	15 minutes
;#
;#		2.4  References:
;#			PAGES:  V_STATUS, V_TEMP_STAT, V_VOLT_HKCAL, I_EXP_STAT
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			Procedure call for K_EXP_MON_ENA
;#
;#		3.2	Critical Activities
;#
;#			None.
;#
;#		3.3	Special Constraints or Activities
;#
;#			The VIRGO commands execute on a 3 minute cycle.  Only one
;#			command can be sent between command executions.
;#**************************************************************************
;#	4.0	STEPS:

BEGIN:
LOCAL ANS,DNUM,DNUMH

IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
	/CLEAR		;Clearing the Command Buffer.
ENDIF

WAIT	;Verify all S/C VIRGO thermistors are within temperature range.

/KNVPWANN		;Switch ON experiment, Branch 1 (Main)
WAIT			;Verify command buffer contents
/SEND

WAIT UNTIL (P@VSPWA = "ON") TIMEOUT 180	;Verify experiment, branch 1 ON

IF (P@VSPWA = "OFF") THEN
	WRITE "THE NOMINAL COMMAND DID NOT WORK!"

	ASK "DO YOU WANT TO TRY THE REDUNDANT COMMAND?"ANS
	LET ANS=%UPPER(ANS)
	IF (ANS="Y") THEN
		/KNVPWANR		;Switch ON experiment, Branch 1 (Redundant)
		WAIT			;Verify command buffer contents
		/SEND

		WAIT UNTIL (P@VSPWA = "ON") TIMEOUT 180	;Verify experiment, branch 1 ON

		IF (P@VSPWA = "OFF") THEN
			WRITE "THE REDUNDANT COMMAND DID NOT WORK EITHER!"
			WRITE "USE BRANCH 2"
			WRITE "START EXP_PREP FOR RED"
			WAIT
		ELSE
		ENDIF
	ELSE
	ENDIF
ELSE
ENDIF

S K_EXP_MON_ENA	;Start procedure to enable experiment monitoring for VIRGO

IF (P@VSPWA="ON") THEN
	/VCGROND1		;Switch ground connection to Main
ELSEIF (P@VSPWB="ON") THEN
	/VCGROND2		;Switch ground connection to Redundant
ENDIF

WAIT			;Verify command buffer contents
/SEND

WAIT 60

/VCLUDEN		;Latch-up detector enable
WAIT			;Verify command buffer contents
/SEND
WAIT 180

/VZML,7000	;Reset PDU
WAIT			;Verify command buffer contents
/SEND

WAIT UNTIL(P@VIPWA = 0.16)	;Verify current increase
WAIT UNTIL(VSDAYOFM=0)		;Verify day of mission reset

WAIT 60

ASK"What is the desired increase in the day of mission?"DNUM
LET DNUMH = %HEX(DNUM,2)	;Convert to two digit hex for TC 

/VZML,A0$DNUMH		;PDU:  TC -> Set Day of Mission to $DNUMH.
WAIT			;Verify command buffer contents
/SEND

WAIT UNTIL (VSTCRETN = H'A0$DNUMH')	;Verify TC return
WAIT UNTIL (VSDAYOFM = H'$DNUMH')		;Verify day of mission

;#************************************************************************** 
;#	5.0	Final Constraints
;#
;#		None.
;#
;#**************************************************************************
ENDPROC