PROC V_FL_SPMA_TST
;Version 5
GOTO BEGIN
;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name:  V_FL_SPMA_TST
;#		   	VIRGO Name:  Sunphotometer SPM-A Test / 
;#					   Commissioning  (PROC 6)  	 
;#		   	Issue/Rev.:  2.5   	
;#			Simulator Validation Status:
;#
;#		1.2	Date Created:  17 JAN 95
;#			    Revision:  1. 31-MAR-95  	CG
;#						2. 21-APR-95	HB
;#						3. 25-APR-95	CG
;#						4. 08-AUG-95	HB
;#						5. 31-AUG-95	HB
;#
;#		1.3	Change Description:	
;#
;#			1.  Updated header information.  Changed memory commands to VZML.
;#			    Added a WAIT UNTIL.  Added comment for use.  Added WAIT to 
;#			    check current consumption, VIPWA, at end of procedure.
;#			2.  Added WAIT 240 statements before the second and third
;#			    commands.
;#			3.  Deleted WAIT 240 statements before the second and third
;#			    commands.
;#			4. Added version number.  Added page references.  Removed TBDs. 
;#			   Added comments. 
;#			5. Changed name from v_ts_spma_tst.  Changed TM checks to 
;#			   eliminate hard WAITs.
;#
;#		1.4	Point of Contact:  Carline Cazeau
;#			FOT Author:  HBenefield	ATSC/SOHO	286-4799
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#
;#			This procedure switches ON and tests the Sunphotometer SPM-A.
;#
;#		2.2	Intended Use:
;#
;#			Swtich ON and test SPM-A.
;#
;#		2.3	Duration:	18 minutes
;#
;#		2.4 	References:
;#			PAGES:  V_STATUS, V_TEMP_STAT, V_VOLT_HKCAL, I_EXP_STAT
;#
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			None.
;#
;#		3.2	Critical Activities
;#
;#			None.
;#
;#		3.3	Special Constraints or Activities
;#
;#			The VIRGO commands execute on a 3 minute cycle.  Only one
;#			command can be sent between command executions.
;#
;#**************************************************************************
;#	4.0	STEPS:

BEGIN:

LOCAL EKS, WHY, ZEE

IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
	/CLEAR		;Clearing the Command Buffer.
ENDIF

/VZML,7010		;Switch ON SPM-A.
WAIT				;Verify contents of command buffer.
/SEND
WAIT UNTIL (VSTCRETN=H'7010')	;Verify TC return

LET EKS = VSPDU MOD 64
WAIT UNTIL(EKS = B'010000')	;Check PDU status (VSPDU=B'XX01 0000').

WAIT	;Check current consumption VIPWA (.005 A increase expected)

/VZML,90B8		;Ref 1, SPM-A, PMO-A, BU:  SPM-A-R
WAIT				;Verify contents of command buffer.
/SEND

WAIT UNTIL (VSTCRETN=H'90B8')	;Check TC return

LET EKS = VSDAS MOD 32
LET WHY = (VSDAS - EKS)/32
LET ZEE = WHY MOD 2

WAIT UNTIL (ZEE = 1)	;Check DAS status (VSDAS = B'XX1X XXXX')

LET EKS = VS1SPA MOD 2
LET WHY = (VS1SPA - EKS)/2

WAIT UNTIL (WHY = 1)	;Check SPM-A status (VS1SPA=B'XX1X')

LET EKS = VS1SPB MOD 2
LET WHY = (VS1SPB - EKS)/2

WAIT UNTIL (WHY = 0)	;Check SPM-B status (VS1SPB=B'XX0X')

WAIT UNTIL (VSBUP=H'8')			;Check Backup status

/VZML,100E		;SPM-A:  Heater 1 & 2 ON, LUD en.
WAIT				;Verify contents of command buffer.
/SEND

WAIT UNTIL (VSTCRETN=H'100E')	;Check TC return
WAIT; Check current consumption  VIPWA (.02 A increase expected)

;#************************************************************************** 
;#	5.0	Final Constraints
;#
;#		None.
;#
;#**************************************************************************
ENDPROC