PROC V_FL_XPMOBDEG
;Version 4
GOTO BEGIN
;
;#**************************************************************************
;#	****PROCEDURE HEADER****
;#
;# 	1.0 	Introduction
;#
;#		1.1	FOT Name:  V_FL_XPMOBDEG  
;#		   	VIRGO Name:  Exit PMO-Degradation Test (PROC 14)	 
;#		   	Issue/Rev:  2.9  	
;#			Simulator Validation Status:
;#
;#		1.2	Date Created:  18 JAN 95
;#			    Revision:  1. 31-MAR-95	HB
;#						2. 08-AUG-95	HB
;#						3. 31-AUG-95	HB
;#						4. 01-FEB-95 	CQ
;#		1.3	Change Description:	
;#
;#			1. Updated all memory load commands to VZML.  Changed name from
;#			   V_TS_XBUP_PMOB to V_TS_XPMOBDEG.  Added SV "TM" B before 
;#			   binary telemetry checks.
;#			2. Added version number.  Added page references.  Removed TBDs.
;#			3. Made flight ready.  Changed name from v_ts_xpmobdeg.  Changed
;#			   TM checks to eliminate hard WAITs.
;#			4. Modify the proc per OCD #177 submitted by PI.
;#
;#		1.4	Point of Contact:  Carline Cazeau
;#			FOT Author:  HBenefield	ATSC/SOHO	286-4799
;#
;#**************************************************************************
;#	2.0	Description
;#
;#		2.1	Narrative Description
;#
;#			This procedure contains the sequence to return to nominal 
;#			mode (AA), stop shutter activity, and close the cover of PMO-B.
;#
;#		2.2	Intended Use:
;#
;#			In flight, this will be done by time tagged/off-line commands.
;#
;#		2.3	Duration:	 18 minutes
;#
;#		2.4  References:
;#			PAGES:  V_STATUS, V_TEMP_STAT, V_VOLT_HKCAL, I_EXP_STAT
;#
;#**************************************************************************
;#	3.0	Instructions for Use:
;#
;#		3.1	Parameters Required
;#
;#			None.
;#
;#		3.2	Critical Activities
;#
;#			None.
;#
;#		3.3	Special Constraints or Activities
;#
;#			The VIRGO commands execute on a 3 minute cycle.  Only one
;#			command can be sent between command executions.
;#
;#**************************************************************************
;#	4.0	STEPS:

BEGIN:

LOCAL EKS, WHY, ZEE

IF (P@CMD_STATE#TELECOMMAND = "AVAILABLE") THEN
ELSE
	/CLEAR		;Clearing the Command Buffer.
ENDIF

/VZML,4008		;PMO-B:  LU en, shutter closed.
WAIT				;Verify contents of command buffer.
/SEND

WAIT UNTIL(VSTCRETN=H'4008')		;Check TC return.

/VZML,8005		;Cover PMO-B closed.
WAIT				;Verify contents of command buffer.
/SEND

WAIT UNTIL(VSTCRETN=H'8005')		;Check TC return.

/VZML,90BF		;Ref1, SPM-A, PMO-A, BU:  SPM-B, PMO-V-B.
WAIT				;Verify contents of command buffer.
/SEND

WAIT UNTIL(VSTCRETN=H'90BF')		;Check TC return.

LET EKS = VSDAS MOD 32
LET WHY = (VSDAS - EKS)/32
LET ZEE = WHY MOD 2

WAIT UNTIL (ZEE = 1)	;Check DAS status (VSDAS = B'XX1X XXXX')

LET EKS = VS1PMA MOD 8
LET WHY = (VS1PMA - EKS)/8

WAIT UNTIL (WHY = 1)	;Check PMO6-A status (VS1PMA=B'1XXX')

LET EKS = VS1PMB MOD 8
LET WHY = (VS1PMB - EKS)/8

WAIT UNTIL (WHY = 0)	;Check PMO6-B status (VS1PMB=B'0XXX')

LET EKS = VS1SPA MOD 2
LET WHY = (VS1SPA - EKS)/2

WAIT UNTIL (WHY = 1)	;Check SPM-A status (VS1SPA=B'XX1X')

LET EKS = VS1SPB MOD 2
LET WHY = (VS1SPB - EKS)/2

WAIT UNTIL (WHY = 0)	;Check SPM-B status (VS1SPB=B'XX0X')

WAIT UNTIL(VSBUP=H'F')			;Check Backup status.

/VZML,5003		;DIARAD TO MODE RIGHT
WAIT				;VERIFY CONTENTS OF COMMAND BUFFER
/SEND

WAIT UNTIL (VSTCRETN = H'5003')	;CHECK TC RETURN

WAIT 1800			;NEED TO RUN IN THIS MODE FOR 30 MINS
				;BEFORE CONTINUING CHECK WITH PI BEFORE
				;PROCEEDING

/VZML,5002		;DIARAD TO MODE LEFT
WAIT				;VERIFY CONTENTS OF COMMAND BUFFER
/SEND

WAIT UNTIL (VSTCRETN = H'5002')	;CHECK TC RETURN

;#************************************************************************** 
;#	5.0	Final Constraints
;#
;#		None.
;#
;#**************************************************************************
ENDPROC